home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 7
/
FM Towns Free Software Collection 7.iso
/
data
/
nos107c
/
nosmain.plt
< prev
next >
Wrap
Text File
|
1993-11-30
|
21KB
|
770 lines
/************************************************************************
* Nifty Offline Signup *
* Presented by -なる-☆ (PGA01332)& *
* Yama-chan (PEE01244) *
*************************************************************************/
/* メモ&ファイル */
var MEMOno[1];
var BELFIL[64];
/* 設定ファイルのパス名 */
var SETFILE [64];
var SETFILE1[64];
/* ディレクトリ */
var TEMP [64];
var TEMP2 [64];
var SOUND [64];
var SOUND2 [64];
/* 画面背景色 */
var R[3]; var G[3]; var B[3];
var ROAD1[30]; var ROAD2[30]; var ROAD3[30];
var DIAL[1];
var MODEM [50];
var SERno[8]; var AGRno[8]; var ComID[8];
var LINEno[2]; var OPEN[1];
var NAME[16]; var Lname[15]; var Fname[15];
var CITY[2]; var myCITY[10]; var RmyCITY [32];
var myBANCHI[20]; var myKATAGAKI[20];
var RmyBANCHI[30]; var RmyKATAGAKI[30];
var YUBINno[6]; var TELno[20];
var OFFICE[60]; var KAKARI[60]; var OFFICEno[20];
var CLEDIT[2]; var MEMBER[19]; var LIMIT[5];
var MAKER[2]; var MACHINE[20];
var YesNo[1];
/* ID & PASSWORD */
var ID[16]; var PW[16];
/* 初期環境設定 */
%init {
case (R<>{} && G<>{} && B<>{},{Yes},{backclr(R,G,B)});
case (@tail(BELFIL,{.}),
{snd},{bellfile(BELFIL)},
{SND},{bellfile(BELFIL)});
case (@nochar(SOUND)==3,
{No}, {SOUND2:=SOUND|{\}},
{Yes},{SOUND2:=SOUND});
case (SOUND<>{}&&@setcdir2(SOUND)={No},{Yes},{mkdir2(SOUND)});
};
/* N.O.S.のヴァージョン・レベル */
%VERLEV {Ver 1.07c};
%VerLev {Ver1.07c};
%DEBUG {No}; /* デバッグモード */
/* 音声ファイル 出力 処理 */
%BELL @xc({07});
%SNDMSG {
[file]
case (SOUND2={}||SOUND2={},
{No}, {case (@filechk(SOUND2|file),
{Yes},{snd(SOUND2|file)},
{No}, {display(BELL)})},
{Yes}, {display(BELL)}
);
};
/* パラメタで指定されたディレクトリへ移動する(「A:\」と「A:」の両方が可能) */
%setcdir2{
[dir]
%dir2 @case(@nochar(dir),2,{im(dir|{\})},,{im(dir)});
setcdir(dir2)
};
/* 指定されたディレクトリー配下に,第2パラメターで指定されたディレクトリを
(もし,無ければ)作成する。 */
%mkdir {
[dir,name]
dispoff({Yes});
case (@setcdir2(dir),
{Yes},{command({mkdir }|name)},
{No},
{
select ({装置(}|dir|{)が使えませんが?},
999,{},
{ もう一回やってみる },{mkdir(dir,name)},
{ ディレクトリを作成しない },{},
{ 処理を中止する },{stop});
});
dispoff({No})
};
/* 指定されたディレクトリーを(もし,無ければ)作成する。 */
%mkdir2 {
[dir]
case (@setcdir2(dir),
{Yes},,
{No},{mkdir2(@body(dir,,{\}));
mkdir(@body(dir,,{\}),@tail(dir,{\}));}
);
};
/* 全ての MEMO を クローズ する */
%CloseAllMemo{
case (@mlast!=0 && @mcheck==0,{Yes},{mopen(@mlast)});
case (@mcheck!=0,{Yes},
{loop ({mclose(2); im(@mcheck!=0);});
});
};
/* MEMO を クリア する */
%DELmemo{
case(@mcheck,{0},{mopen(1); }); mclose(3);
};
%ALLClear{
loop ({
case (@mlast<>{0},
{Yes},{DELmemo; im({Yes});},
{No},{im({No});
});
});
};
%DELAllMemo{
case (@mlast > 0,
{Yes},
{
MEMOno:=0;
CloseAllMemo;
loop ({mopen(@mlast);
mclose(3);
im(@mlast > 0);
});
});
};
%PLTSTOP{ /* パイロット停止処理(PF20キーで再起動) */
display({\nN.O.S.(}|VerLev|{) を終了します(PF20キーで再起動)\n});
setpf(20,{footnote({NOSMAIN.PLT Loading,,,♪});}|
{#}|CDIR2|{NOSMAIN.PLT});
};
/* 背景色の設定 */
%setCOLOR{
case (R,{},{R:=0});
case (G,{},{G:=0});
case (B,{},{B:=0});
SNDMSG({erande_f.snd});
footnote({背景色の変更中,,,♪( 変更前 R=}|R|{,G=}|G|{,B=}|B|{ )});
loop ({
select ({[赤・緑・青]を左クリックしてネ☆}|
{(現在の色は R=}|R|{,G=}|G|{,B=}|B|{)},
999,{im({No})},
{赤↑ワン・クリック[+10]},
{case(R<246,{Yes},{R:=R+10;backclr(R,G,B)});im({Yes})},
{緑↑ワン・クリック[+10]},
{case(G<246,{Yes},{G:=G+10;backclr(R,G,B)});im({Yes})},
{青↑ワン・クリック[+10]},
{case(B<246,{Yes},{B:=B+10;backclr(R,G,B)});im({Yes})},
{赤↓ワン・クリック[-10]},
{case(R> 9,{Yes},{R:=R-10;backclr(R,G,B)});im({Yes})},
{緑↓ワン・クリック[-10]},
{case(G> 9,{Yes},{G:=G-10;backclr(R,G,B)});im({Yes})},
{青↓ワン・クリック[-10]},
{case(B> 9,{Yes},{B:=B-10;backclr(R,G,B)});im({Yes})},
{ 終 了 },{im({No})}
);
});
};
/* ドライブディレクトリ & 背景色設定書き込み制御文 */
%setINIT{
%snddir SOUND;
%colorR R;
%colorG G;
%colorB B;
loop ({
footnote({N.O.S.初期環境情報の設定処理中,,,♪});
SNDMSG({nyuryo_f.snd});
%a @plane(
{c 初期環境情報を入力してネ☆(^_^)/♪\n}|
{c\n}|
{t サウンド・ファイル格納用ディレクトリ/\n}|
{c(ドライブやディレクトリは、フルパスで指定}|
{(末尾の「\」は不要)\n}|
{c サウンド・ファイルを使用しない場合は、ドライブのみ指定)\n}|
{c\n}|
{t 背景色[赤]( 0~255)/xxx\n}|
{t 背景色[緑]( 0~255)/xxx\n}|
{t 背景色[青]( 0~255)/xxx\n}|
{c\n}|
{s / 設定する \n},
snddir,colorR,colorG,colorB);
%snddir @head(@getline(a,1,1),{\n});
%colorR @head(@getline(a,2,1),{\n});
%colorG @head(@getline(a,3,1),{\n});
%colorB @head(@getline(a,4,1),{\n});
%ok @head(@getline(a,5,1),{\n});
case (ok,
{ 1}, {
SOUND:=snddir;mkdir2(SOUND);
R:=colorR;
G:=colorG;
B:=colorB;
im({No});
},
, {im({Yes})}
);
});
};
/* アクセスポイント電話番号の設定制御文 */
%setTEL {
case(DIAL,{T},{DIAL:={1}},{P},{DIAL:={2}});
%rd1 ROAD1;
%rd2 ROAD2;
%dial DIAL;
loop ({
footnote({アクセス・ポイント電話番号の設定処理中,,,♪});
SNDMSG({nyuryo_f.snd});
%a @plane(
{cアクセス・ポイントの電話番号を設定してネ☆(^_^)/♪\n}|
{tROAD1の電話番号/\n}|
{s(選択ボタンをクリックで検索メニュー表示)/選択ボタン\n}|
{c ROAD1の場合、電話番号の後に スラッシュ「/」と「通信速度」\n}|
{c を追加してください(例:「/1200」又は「/2400」)\n}|
{c\n}|
{tROAD2の電話番号/\n}|
{s(選択ボタンをクリックで検索メニュー表示)/選択ボタン\n}|
{c\n}|
{r 電話回線の種類 /プッシュホン式 /ダイヤルパルス式\n}|
{s / 設定する \n},
rd1,rd2,dial);
%rd1 @head(@getline(a,1,1),{\n});
%rd1sel @head(@getline(a,2,1),{\n});
%rd2 @head(@getline(a,3,1),{\n});
%rd2sel @head(@getline(a,4,1),{\n});
%dial @head(@getline(a,5,1),{\n});
%ok @head(@getline(a,6,1),{\n});
case(rd1sel,{ 1},{setcdir(cdir); #ROAD1.PLP; im({Yes})});
case(rd2sel,{ 1},{setcdir(cdir); #ROAD2.PLP; im({Yes})});
case(ok,{ 1},
{
ROAD1:=rd1;
ROAD2:=rd2;
DIAL:=@case(dial,{ 1},{im({T})},{ 2},{im({P})},
,{im({P})});
im({No});
},
, {im({Yes})});
});
};
/* NIFTYでの初期情報設定書き込み制御文 */
%setNIFTY{
case(OPEN,{},{OPEN:={1}},{1},{OPEN:={2}});
%modem MODEM;
%serno SERno;
%agrno AGRno;
%lineno LINEno;
%comid ComID;
%open OPEN;
loop ({
footnote({NIFTY関係の情報の設定処理中,,,♪});
SNDMSG({nyuryo_f.snd});
%a @plane(
{c NIFTY 関係の情報を入力してネ☆(^_^)/♪\n}|
{t ATモデム・コマンド/\n}|
{s(選択ボタンをクリックで検索メニュー表示)/選択ボタン\n}|
{c\n}|
{t SERIAL NUMBER (半角で8文字)/xxxxxxxx\n}|
{t AGREEMENT NUMBER(半角で8文字)/xxxxxxxx\n}|
{t 画面の最大表示行数(9 ~ 99 ) /xx\n}|
{r Compu-Serve IDの取得 /する /しない \n}|
{r 個人情報の公開 /公開 /非公開 \n}|
{c\n}|
{s / 設定する \n},
modem,serno,agrno,lineno,comid,open);
%modem @head(@getline(a,1,1),{\n});
%mselct @head(@getline(a,2,1),{\n});
%serno @head(@getline(a,3,1),{\n});
%agrno @head(@getline(a,4,1),{\n});
%lineno @head(@getline(a,5,1),{\n});
%comid @head(@getline(a,6,1),{\n});
%open @head(@getline(a,7,1),{\n});
%ok @head(@getline(a,8,1),{\n});
case(mselct,{ 1},{setcdir(cdir); #MODEM.PLP; im({Yes})});
case (ok,
{ 1},
{
MODEM:=modem;
SERno:=serno;
AGRno:=agrno;
LINEno:=lineno;
ComID:=@case(comid,{ 1},{im({1})},{ 2},{im({2})},
,{im({2})});
OPEN:=@case(open,{ 1},{im({})},{ 2},{im({1})},
,{im({1})});
im({No});
},
, {im({Yes})}
);
});
};
/* 氏名設定書き込み制御文 */
%setNAME{
%name NAME;
%lname Lname;
%fname Fname;
loop ({
footnote({氏名等の情報を設定処理中,,,♪});
SNDMSG({nyuryo_f.snd});
%a @plane(
{c 氏名を入力してネ☆(^_^)/♪\n}|
{c\n}|
{t 氏と名を入力(漢字で8文字まで) }|
{/xxxxxxxxxxxxxxxx\n}|
{c\n}|
{t 氏(ローマ字で20文字まで)例:YAMADA)}|
{/xxxxxxxxxxxxxxxxxxxx\n}|
{c\n}|
{t 名前(ローマ字で20文字まで)例:TARO)}|
{/xxxxxxxxxxxxxxxxxxxx\n}|
{c\n}|
{s / 設定する \n},
name,lname,fname);
%name @head(@getline(a,1,1),{\n});
%lname @head(@getline(a,2,1),{\n});
%fname @head(@getline(a,3,1),{\n});
%ok @head(@getline(a,4,1),{\n});
case (ok,
{ 1}, {
NAME:=name;
Lname:=lname;
Fname:=fname;
im({No});
},
, {im({Yes})}
);
});
};
/* 住所・電話番号設定書き込み制御文 */
%setADRS{
%city CITY;
%mycity myCITY;
%rmycity RmyCITY;
%mybanchi myBANCHI;
%rmybanchi RmyBANCHI;
%mykatagaki myKATAGAKI;
%rmykatagaki RmyKATAGAKI;
%yubinno YUBINno;
%telno TELno;
loop ({
footnote({住所・肩書・電話番号等々の設定処理中,,,♪});
SNDMSG({nyuryo_f.snd});
%a @plane(
{c住所/肩書/郵便・電話番号を入力してネ☆(^_^)/♪\n}|
{t都道府県コード(選択ボタンをクリックで検索メニュー表示)/xx\n}|
{s /選択ボタン\n}|
{t市郡名(例:横浜市,千代田区等) /xxxxxxxxxx\n}|
{t市郡名(ローマ字 23区は区名も 例:YOKOHAMASHI)/\n}|
{t所番地(20文字 例:大山 6-26-1)/\n}|
{t所番地(ローマ字で30文字 例:Oyama 6-chome)/\n}|
{t方書(20文字 例:ベルハイム 206 )/\n}|
{t方書(ローマ字で30文字 例:BERUHAIMU 206)/\n}|
{t郵便番号(例:102)/xxxxxx\n}|
{t自宅電話番号(市外局番も 例:03-5471-5800)/\n}|
{s / 設定する \n},
city,mycity,rmycity,mybanchi,rmybanchi,mykatagaki,
rmykatagaki,yubinno,telno);
%city @head(@getline(a,1,1),{\n});
%citysel @head(@getline(a,2,1),{\n});
%mycity @head(@getline(a,3,1),{\n});
%rmycity @head(@getline(a,4,1),{\n});
%mybanchi @head(@getline(a,5,1),{\n});
%rmybanchi @head(@getline(a,6,1),{\n});
%mykatagaki @head(@getline(a,7,1),{\n});
%rmykatagaki @head(@getline(a,8,1),{\n});
%yubinno @head(@getline(a,9,1),{\n});
%telno @head(@getline(a,10,1),{\n});
%ok @head(@getline(a,11,1),{\n});
case(citysel,{ 1},{setcdir(cdir); #CITY.PLP; im({Yes})});
case (ok,
{ 1}, {
CITY:=city;
myCITY:=mycity;
RmyCITY:=rmycity;
myBANCHI:=mybanchi;
RmyBANCHI:=rmybanchi;
myKATAGAKI:=mykatagaki;
RmyKATAGAKI:=rmykatagaki;
YUBINno:=yubinno;
TELno:=telno;
im({No});
},
, {im({Yes})}
);
});
};
/* 勤務先・電話番号設定書き込み制御文 */
%setOFFICE{
%office OFFICE;
%kakari KAKARI;
%officeno OFFICEno;
loop ({
footnote({勤務先・電話番号等の設定処理中,,,♪});
SNDMSG({nyuryo_f.snd});
%a @plane(
{c 勤務先・電話番号を入力してネ☆(^_^)/♪\n}|
{c\n}|
{t 勤務先(全角30文字以内)}|
{/\n}|
{c\n}|
{t 部課名(全角30文字以内)}|
{/\n}|
{c\n}|
{t 電話番号(市外局番も 例:03-5471-5800)/\n}|
{c\n}|
{s / 設定する \n},
office,kakari,officeno);
%office @head(@getline(a,1,1),{\n});
%kakari @head(@getline(a,2,1),{\n});
%officeno @head(@getline(a,3,1),{\n});
%ok @head(@getline(a,4,1),{\n});
case (ok,
{ 1}, {
OFFICE:=office;
KAKARI:=kakari;
OFFICEno:=officeno;
im({No});
},
, {im({Yes})}
);
});
};
/* クレジットカード・会員番号設定書き込み制御文 */
%setCLEDIT{
%cledit CLEDIT;
%member MEMBER;
%limit LIMIT;
loop ({
footnote({クレジットカード・会員番号等の設定処理中,,,♪});
SNDMSG({nyuryo_f.snd});
%a @plane(
{c クレジットカード・会員番号を入力してネ☆(^_^)/♪\n}|
{t クレジットカード種別(選択ボタンをクリックで検索メニュー表示)}|
{/xx\n}|
{s /選択ボタン\n}|
{c\n}|
{t 会員番号(例:XXXX XXXX XXXX XXXX)}|
{/xxxxxxxxxxxxxxxxxxx\n}|
{c 有効期限(例:11/95)\n}|
{t 有効期限 /xxxxx\n}|
{c\n}|
{s / 設定する \n},
cledit,member,limit);
%cledit @head(@getline(a,1,1),{\n});
%clsel @head(@getline(a,2,1),{\n});
%member @head(@getline(a,3,1),{\n});
%limit @head(@getline(a,4,1),{\n});
%ok @head(@getline(a,5,1),{\n});
case(clsel,{ 1},{setcdir(cdir); #CLEDIT.PLP; im({Yes})});
case (ok,
{ 1}, {
CLEDIT:=cledit;
MEMBER:=member;
LIMIT:=limit;
im({No});
},
, {im({Yes})}
);
});
};
/* パソコンのメーカ・機種設定書き込み制御文 */
%setMACHINE{
%maker MAKER;
%machine MACHINE;
loop ({
footnote({メーカー及び機種名の設定処理中,,,♪});
SNDMSG({nyuryo_f.snd});
%a @plane(
{c メーカー番号及び機種名を入力してネ☆(^_^)/♪\n}|
{c\n}|
{t パソコン/ワープロのメーカ番号 /xx\n}|
{s(選択ボタンをクリックで検索メニュー表示)/選択ボタン\n}|
{c\n}|
{t パソコン・ワープロの使用機種名 /xxxxxxxxxxxxxxxx\n}|
{c\n}|
{s / 設定する \n},
maker,machine);
%maker @head(@getline(a,1,1),{\n});
%mksel @head(@getline(a,2,1),{\n});
%machine @head(@getline(a,3,1),{\n});
%ok @head(@getline(a,4,1),{\n});
case(mksel,{ 1},{setcdir(cdir); #MAKER.PLP; im({Yes})});
case (ok,
{ 1}, {
MAKER:=maker;
MACHINE:=machine;
im({No});
},
, {im({Yes})}
);
});
};
/* 設定情報をファイルに保存する */
%writeSET{
[file]
setcdir(CDIR);
dispoff(!DEBUG);
command({copy }|file|{ *.BAK});
command({del }|file);
dispoff({No});
%MEMOno @mlast+1;
%SETdata{[HEAD,DATA]
madd(MEMOno,HEAD|{:=}|@xc({7b})|DATA|@xc({7d})|{;\n});
};
SETdata({SOUND },SOUND);
SETdata({R },R);
SETdata({G },G);
SETdata({B },B);
SETdata({ROAD1 },ROAD1);
SETdata({ROAD2 },ROAD2);
SETdata({ROAD3 },ROAD3);
SETdata({DIAL },DIAL);
SETdata({MODEM },MODEM);
SETdata({SERno },SERno);
SETdata({AGRno },AGRno);
SETdata({NAME },NAME);
SETdata({Lname },Lname);
SETdata({Fname },Fname);
SETdata({CITY },CITY);
SETdata({myCITY },myCITY);
SETdata({RmyCITY},RmyCITY);
SETdata({myBANCHI},myBANCHI);
SETdata({RmyBANCHI},RmyBANCHI);
SETdata({myKATAGAKI},myKATAGAKI);
SETdata({RmyKATAGAKI},RmyKATAGAKI);
SETdata({YUBINno},YUBINno);
SETdata({TELno },TELno);
SETdata({OFFICE },OFFICE);
SETdata({KAKARI },KAKARI);
SETdata({OFFICEno},OFFICEno);
SETdata({ComID },ComID);
SETdata({CLEDIT },CLEDIT);
SETdata({MEMBER },MEMBER);
SETdata({LIMIT },LIMIT);
SETdata({MAKER },MAKER);
SETdata({MACHINE},MACHINE);
SETdata({LINEno },LINEno);
SETdata({OPEN },OPEN);
SETdata({YesNo },YesNo);
SETdata({ID },ID);
SETdata({PW },PW);
loop ({
case (@mcheck<>{0},
{Yes},{mclose(1); im({Yes});},
{No},{im({No})});
});
mwrite(file,MEMOno);
mopen(MEMOno,0,21,639,459);
mclose(3);
/* display({\n☆設定内容を保存しました☆\n\n}); */
};
/* 未設定情報を画面に表示する */
%MSGDSP{
%MSGdata{
[PARA,MSG]
case(PARA,{},{display(MSG|{が未設定です☆\n})});
};
MSGdata(ROAD1 && ROAD2,{☆アクセスポイントの電話番号});
MSGdata(MODEM,{☆モデムコマンド});
MSGdata(SERno,{☆シリアルナンバー});
MSGdata(AGRno,{☆アグリーメントナンバー});
MSGdata(NAME,{☆氏名});
MSGdata(Lname,{☆ラストネーム});
MSGdata(Fname,{☆ファーストネーム});
MSGdata(CITY,{☆都道府県名の番号});
MSGdata(myCITY,{☆住所});
MSGdata(RmyCITY,{☆住所(ローマ字)});
MSGdata(myBANCHI,{☆番地});
MSGdata(RmyBANCHI,{☆番地(ローマ字)});
MSGdata(YUBINno,{☆郵便番号});
MSGdata(TELno,{☆電話番号});
MSGdata(OFFICE,{☆勤務先});
MSGdata(KAKARI,{☆所属});
MSGdata(OFFICEno,{☆勤務先電話番号});
MSGdata(CLEDIT,{☆クレジットカードの種別});
MSGdata(MEMBER,{☆会員番号});
MSGdata(LIMIT,{☆有効期限});
MSGdata(MAKER,{☆メーカ番号});
MSGdata(MACHINE,{☆機種名});
MSGdata(LINEno,{☆画面最大表示行数});
case (YesNo,{1},
{display({☆オンライン・サインアップ手続きを完了します☆\n});
display({☆中止する場合は「AUTO」アイコンをクリック後「Pilot Stop?」}|
{をクリックしてください☆\n\n})});
};
%RETRY{
loop ({
footnote({再度設定内容の確認処理中,,,♪});
SNDMSG({erande_f.snd});
select ({ 設定メニューを選んでネ☆(^_^)/♪},
60, {setcdir(cdir)},
{ アクセスポイントの設定(AP) },
{setcdir(cdir); setTEL; im({Yes})},
{ NIFTYに関する設定( NIFTY ) },
{setcdir(cdir); setNIFTY; im({Yes})},
{ 氏名・ファースト(ラスト)ネーム (NAME) },
{setcdir(cdir); setNAME; im({Yes})},
{ 住所・方書・電話番号 (ADDRESS)},
{setcdir(cdir); setADRS; im({Yes})},
{ 勤務先・所属・電話番号(OFFICE)},
{setcdir(cdir); setOFFICE; im({Yes})},
{ クレジットカード・会員番号(CLEDIT)},
{setcdir(cdir); setCLEDIT; im({Yes})},
{ 使用機種・メーカ名 (MACHINE)},
{setcdir(cdir); setMACHINE; im({Yes})},
{ 操作説明(マニュアル)をみる },
{setcdir(cdir); #HELP.PLP; im({Yes})},
{ 終 了 ( メイン・メニューへ )},{im({No})});
});
writeSET({USER_SET.SET});
};
%setTRY {
setTEL;
setNIFTY;
setNAME;
setADRS;
setOFFICE;
setCLEDIT;
setMACHINE;
writeSET({USER_SET.SET});
};
/* ヘルプ画面表示の選択 */
%HELP{
footnote({メニューをマウス左クリックで選択してください});
SNDMSG({erande_f.snd});
select ({ メニューを選んでネ☆(^_^)/♪},
,,
{ 操作説明(マニュアル)をみる },{setcdir(cdir);#HELP.PLP;},
{ 先へ進む ( 初期設定 ) },{});
};
/* オープニング画面表示 */
%setBEGIN{
loop ({
footnote({N.O.S.オープニング ,,,♪});
SNDMSG({BELL.SND});
%a @plane(
{c ☆☆☆オートパイロットマクロの世界へようこそ!!☆☆☆\n}|
{c\n}|
{c NIFTY-Serve オンライン・サインアップを実行したい人へ\n}|
{c\n}|
{c このマクロは、通信開始前に必要な項目を設定すること\n}|
{c\n}|
{c で、効率良くサインアップの手続きを完了します(^_^)\n}|
{c\n}|
{c < 入力の方法について >\n}|
{c 青色の[ ]・・・ キーボードから入力します\n}|
{c 青色の[選択ボタン]・・・ マウス左クリックで一覧メニューを表示します\n}|
{c 赤色の[ ●ボタン ]・・・ マウス左クリックで項目を選択します\n}|
{c その他、青色の各メニューは、マウス左クリックで選択します\n}|
{c\n}|
{s 宜しければ[次頁]ボタンをマウス左クリックしてください→ / 次頁 },
);
%ok @head(@getline(a,1,1),{\n});
case(ok,{ 1},{HELP;im({No})},,{im({Yes})});
});
};
/************************************************************************
* メインメニュー 処理 *
*************************************************************************/
%cdir @getcdir;
%CDIR @getcdir;
%CDIR2 @case (@nochar(CDIR)==3,
{Yes}, {im(CDIR)},
{No},{im(CDIR|{\})});
%NOSMAIN{
display({\nN.O.S.(}|VerLev|{) を開始します(^_^)/♪\n});
display({開始時刻は -}|@getchar(@daylong,16,8)|{- です\n});
DELAllMemo;
setBEGIN;
case (@nochar(CDIR)==3,
{No}, {SETFILE:=CDIR|{\}|{USER_SET.SET}},
{Yes},{SETFILE:=CDIR|{USER_SET.SET}});
case (@filechk(SETFILE),
{Yes},{setcdir(CDIR); #USER_SET.SET; init;},
{No}, {setcdir(CDIR); #INIT_SET.SET; setINIT; init; setTRY;}
);
setcdir(cdir);
loop ({
footnote({*** Nifty Offline Signup *** }|VerLev);
SNDMSG({erande_f.snd});
select ({ 処理メニューを選んでネ☆(^_^)/♪},
60, {setcdir(cdir)},
{[1] 初期環境設定を行う ( INIT )},
{setcdir(cdir); setINIT; setCOLOR; init; im({Yes})},
{[2] 最初から設定を行う ( TRY )},
{setcdir(cdir); setTRY; im({Yes})},
{[3] 再度 設定内容を確認する ( RETRY )},
{setcdir(cdir); #USER_SET.SET; RETRY; im({Yes})},
{[4] 全ての設定項目を保存する ( SAVE )},
{writeSET({USER_SET.SET}); im({Yes})},
{[5]NIFTY-Serveへ接続開始( CONNECT )},
{setcdir(cdir); #USER_SET.SET; MSGDSP; #CONNECT.PLP;
case (ID={}, {Yes},{writeSET({USER_SET.SET})},
{No},{ID:=@getchar(ID,1,8);
writeSET(ID|{.SET})});
init; im({Yes});
},
{[6] 操作説明(マニュアル)をみる ( HELP )},
{setcdir(cdir); #HELP.PLP; im({Yes})},
{[7] 終 了 ( EXIT )},
{setcdir(cdir); PLTSTOP; im({No})}
);
});
};
footnote({N.O.S.起動中,,,♪});
case (@mlast > 0,
{Yes},
{
SNDMSG ({kaknin_f.snd});
select ({編集中のメモを削除する?},
999,{im({No})},
{ す る },{NOSMAIN},
{ しない },
{
SNDMSG({BELL.SND});
footnote({N.O.S.の起動中止します(PF20キーで再起動)});
PLTSTOP;
wait(2);
});
},
{No},{NOSMAIN}
);